stagit

Personal Stagit Fork
git clone https://github.com/maydayv7/stagit

flake.nix (1866B)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
{
  description = "Personal Stagit Fork";
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs";
    utils.url = "github:numtide/flake-utils";
  };

  outputs =
    { nixpkgs, utils, ... }:
    utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = nixpkgs.legacyPackages.${system};
        pythonEnv = pkgs.python3.withPackages (
          ps: with ps; [
            pygments
            markdown
            pymdown-extensions
            (buildPythonPackage rec {
              pname = "markdown_callouts";
              version = "0.4.0";
              format = "pyproject";
              nativeBuildInputs = [ hatchling ];
              propagatedBuildInputs = [ markdown ];
              src = fetchPypi {
                inherit pname version;
                sha256 = "sha256-ftLJBIaWcFinOlR3gRIZg4OVItZwQa5SxJeWFvGyt0Y=";
              };
            })
          ]
        );
      in
      {
        packages.default = pkgs.stdenv.mkDerivation {
          pname = "stagit";
          version = "1.2-custom";
          src = ./.;
          buildInputs = [ pkgs.libgit2 ];
          nativeBuildInputs = [
            pkgs.pkg-config
            pkgs.makeWrapper
          ];

          buildPhase = ''
            make PREFIX=$out \
              STAGIT_CFLAGS="-I${pkgs.libgit2}/include" \
              STAGIT_LDFLAGS="-L${pkgs.libgit2}/lib -lgit2"
          '';

          installPhase = ''
            mkdir -p $out/bin
            mkdir -p $out/share/doc/stagit

            cp stagit $out/bin/
            cp stagit-index $out/bin/
            cp favicon.png $out/share/doc/stagit/

            cp render.py $out/bin/render
            sed -i "1i #!${pythonEnv}/bin/python3" $out/bin/render
            chmod +x $out/bin/render
            wrapProgram $out/bin/stagit --prefix PATH : "$out/bin"
          '';
        };
      }
    );
}