dotfiles

My PC Dotfiles & Website
git clone https://github.com/maydayv7/dotfiles

_module.nix (1269B)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
## Secrets Management ##
{
  config,
  inputs,
  ...
}: let
  inherit (config) util;
  inherit (config.flake) files;
in {
  flake.modules = {
    # System-Wide Secrets
    nixos.secrets = {
      config,
      pkgs,
      ...
    }: let
      path = files.path.gpg;
    in {
      imports = [inputs.sops.nixosModules.sops];

      config = {
        environment = {
          persist.directories = [path];
          systemPackages = [pkgs.sops];
        };

        sops = {
          gnupg.home = path;
          secrets = let
            directory = ./. + "/${config.networking.hostName}";
          in
            util.map.secrets {directory = ./.;}
            // (
              if (builtins.pathExists directory)
              then util.map.secrets {inherit directory;}
              else {}
            );
        };
      };
    };

    # Per-User Secrets
    homeManager.secrets = {config, ...}: {
      imports = [inputs.sops.homeManagerModules.sops];
      sops = {
        gnupg.home = "${config.home.homeDirectory}/.gnupg";
        secrets = let
          directory = ./user + "/${config.home.username}";
        in
          if (builtins.pathExists directory)
          then util.map.secrets {inherit directory;}
          else {};
      };
    };
  };
}