dotfiles

My PC Dotfiles & Website
git clone https://github.com/maydayv7/dotfiles

_obsidian.nix (1559B)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
# Obsidian Package Builders #
{
  lib,
  stdenvNoCC,
  fetchFromGitHub,
  fetchurl,
}: {
  mkTheme = {
    pname,
    meta ? {},
    ...
  } @ metadata:
    stdenvNoCC.mkDerivation {
      inherit pname;
      version = builtins.substring 0 7 metadata.rev;

      src = fetchFromGitHub {
        inherit (metadata) owner repo rev;
        hash = metadata.sha256;
      };

      dontBuild = true;
      installPhase = ''
        runHook preInstall
        mkdir -p $out
        cp manifest.json theme.css $out/
        runHook postInstall
      '';

      meta = {maintainers = ["maydayv7"];} // meta;
    };

  mkPlugin = {
    pname,
    owner,
    repo,
    version,
    hashes,
    meta ? {},
    ...
  }: let
    base = "https://github.com/${owner}/${repo}/releases/download/${version}";
    main = fetchurl {
      url = "${base}/main.js";
      hash = hashes.main;
    };
    manifest = fetchurl {
      url = "${base}/manifest.json";
      hash = hashes.manifest;
    };
    styles =
      if hashes ? styles
      then
        fetchurl {
          url = "${base}/styles.css";
          hash = hashes.styles;
        }
      else null;
  in
    stdenvNoCC.mkDerivation {
      inherit pname version;

      dontUnpack = true;
      installPhase = ''
        runHook preInstall
        mkdir -p $out
        cp ${main} $out/main.js
        cp ${manifest} $out/manifest.json
        ${lib.optionalString (styles != null) "cp ${styles} $out/styles.css"}
        runHook postInstall
      '';

      meta = {maintainers = ["maydayv7"];} // meta;
    };
}