dotfiles

My PC Dotfiles & Website
git clone https://github.com/maydayv7/dotfiles

_mutable.nix (2280B)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
# https://gist.github.com/piousdeer/b29c272eaeba398b864da6abf6cb5daa
{
  config,
  lib,
  ...
}: let
  inherit
    (builtins)
    attrValues
    concatLists
    filter
    foldl'
    map
    ;

  inherit
    (lib)
    assertMsg
    concatLines
    escapeShellArg
    getAttrFromPath
    hm
    mkOption
    recursiveUpdate
    setAttrByPath
    types
    ;

  fileOptionAttrPaths = [
    [
      "home"
      "file"
    ]
    [
      "xdg"
      "configFile"
    ]
    [
      "xdg"
      "dataFile"
    ]
  ];
in {
  options = let
    mergeAttrsList = foldl' recursiveUpdate {};
    fileAttrsType = types.attrsOf (
      types.submodule (_: {
        options.mutable = mkOption {
          type = types.bool;
          default = false;
          description = ''
            Whether to copy the file without the read-only attribute instead of symlinking.
            If you set this to 'true', you must also set 'force' to 'true'.
            Mutable files are not removed when you remove them from your configuration.
            This option is useful for programs that don't have a very good support for read-only configurations.
          '';
        };
      })
    );
  in
    mergeAttrsList (
      map (
        attrPath:
          setAttrByPath attrPath (mkOption {
            type = fileAttrsType;
          })
      )
      fileOptionAttrPaths
    );

  config = {
    home.activation.mutableFileGeneration = let
      allFiles = concatLists (
        map (attrPath: attrValues (getAttrFromPath attrPath config)) fileOptionAttrPaths
      );

      filterMutableFiles = filter (
        file:
          (file.mutable or false)
          && assertMsg file.force "if you specify 'mutable' to 'true' on a file, you must also set 'force' to 'true'"
      );

      mutableFiles = filterMutableFiles allFiles;

      toCommand = file: let
        source = escapeShellArg file.source;
        target = escapeShellArg file.target;
      in ''
        $VERBOSE_ECHO "${source} -> ${target}"
        $DRY_RUN_CMD cp --remove-destination --no-preserve=mode ${source} ${target}
      '';

      command =
        ''echo "Copying mutable home files for $HOME"''
        + concatLines (map toCommand mutableFiles);
    in
      hm.dag.entryAfter ["linkGeneration"] command;
  };
}