dotfiles

My PC Dotfiles & Website
git clone https://github.com/maydayv7/dotfiles

git-runner.nix (1678B)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
## GitHub/GitLab CI Runner Configuration ##
{config, ...}: let
  inherit (config.flake) files;
in {
  flake.modules.nixos.git-runner = {
    config,
    lib,
    pkgs,
    ...
  }: let
    inherit
      (lib)
      mkIf
      mkMerge
      mkOption
      types
      ;
    inherit (config.apps.git) runner;
  in {
    options.apps.git.runner = {
      support = mkOption {
        description = "Support for 'git' Runners";
        type = types.nullOr (
          types.enum [
            "github"
            "gitlab"
          ]
        );
        default = null;
      };
      secret = mkOption {
        description = "Path to Secret for 'git' Runner";
        type = types.str;
        default = "";
      };
    };

    config = mkIf (runner.support != null) (mkMerge [
      {
        assertions = [
          {
            assertion = runner.secret != "";
            message = "Path to Secret for 'git' Runner must be set";
          }
        ];
      }
      (mkIf (runner.support == "github") {
        # GitHub Runner
        environment.systemPackages = [pkgs.act];
        services.github-runners.runner = {
          enable = true;
          url = files.path.repo;
          extraLabels = ["self"];
          tokenFile = runner.secret;
        };
      })

      (mkIf (runner.support == "gitlab") {
        # Docker Support
        virtualisation.docker.enable = true;

        # GitLab Runner
        services.gitlab-runner = {
          enable = true;
          services.default = {
            dockerImage = "alpine";
            tagList = ["self"];
            authenticationTokenConfigFile = runner.secret;
          };
        };
      })
    ]);
  };
}