dotfiles

My PC Dotfiles & Website
git clone https://github.com/maydayv7/dotfiles

flatpak.nix (2043B)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
## Flatpak Configuration ##
{inputs, ...}: {
  flake.modules = {
    nixos.flatpak = {
      config,
      lib,
      pkgs,
      ...
    }: let
      isGnome = config.services.desktopManager.gnome.enable or false;
    in {
      imports = [inputs.flatpak.nixosModules.nix-flatpak];

      xdg.portal.enable = true;
      environment.persist.directories = ["/var/lib/flatpak"];
      system.activationScripts.updateDesktopDatabase.text = "${pkgs.desktop-file-utils}/bin/update-desktop-database /var/lib/flatpak/exports/share/applications";

      services.flatpak = {
        enable = true;
        uninstallUnmanaged = true;

        remotes =
          [
            {
              name = "flathub";
              location = "https://dl.flathub.org/repo/flathub.flatpakrepo";
            }
            {
              name = "flathub-beta";
              location = "https://flathub.org/beta-repo/flathub-beta.flatpakrepo";
            }
          ]
          ++ lib.optionals isGnome [
            {
              name = "gnome-nightly";
              location = "https://nightly.gnome.org/gnome-nightly.flatpakrepo";
            }
          ];

        packages = [
          {
            appId = "com.github.tchx84.Flatseal";
            origin = "flathub";
          }
        ];

        overrides.global = {
          Context = {
            filesystems = [
              "~/.config/dconf:ro"
              "/run/current-system/sw/share/themes:ro"
            ];
            sockets = [
              "wayland"
              "!x11"
              "fallback-x11"
            ];
          };
          Environment = {
            "DCONF_USER_CONFIG_DIR" = ".config/dconf";
            inherit (config.environment.variables) "GTK_THEME";
          };
        };

        update = {
          onActivation = false;
          auto.enable = false;
        };
      };
    };

    homeManager.flatpak = _: {
      home.persist.directories = [
        ".cache/flatpak"
        ".local/share/flatpak"
        ".var/app"
      ];
    };
  };
}